113 lines
2.3 KiB
Bash
113 lines
2.3 KiB
Bash
# Copyright 1999-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
MY_PV=${PV/_p/pl}
|
|
MY_P=${PN}-${MY_PV}
|
|
|
|
inherit desktop dune edo
|
|
|
|
DESCRIPTION="Proof assistant written in O'Caml"
|
|
HOMEPAGE="http://coq.inria.fr/
|
|
https://github.com/coq/coq/"
|
|
SRC_URI="https://github.com/coq/coq/archive/V${MY_PV}.tar.gz
|
|
-> ${P}.tar.gz"
|
|
S="${WORKDIR}"/${MY_P}
|
|
|
|
LICENSE="LGPL-2.1"
|
|
SLOT="0/${PV}"
|
|
KEYWORDS="~amd64 x86"
|
|
IUSE="debug doc gui +ocamlopt test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
dev-ml/zarith:=
|
|
|| (
|
|
dev-ml/num
|
|
<dev-lang/ocaml-4.09.0[ocamlopt?]
|
|
)
|
|
gui? (
|
|
>=dev-ml/lablgtk-3.1.2:3=[sourceview,ocamlopt?]
|
|
>=dev-ml/lablgtk-sourceview-3.1.2:3=[ocamlopt?]
|
|
)
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
dev-ml/findlib
|
|
doc? (
|
|
>=dev-java/antlr-4.7:4
|
|
dev-python/antlr4-python3-runtime
|
|
dev-python/beautifulsoup4
|
|
dev-python/pexpect
|
|
dev-python/sphinx-rtd-theme
|
|
dev-python/sphinxcontrib-bibtex
|
|
dev-tex/latexmk
|
|
dev-texlive/texlive-fontsextra
|
|
dev-texlive/texlive-latexextra
|
|
dev-texlive/texlive-xetex
|
|
media-fonts/freefont
|
|
)
|
|
test? ( dev-ml/ounit2 )
|
|
"
|
|
|
|
DOCS=( CODE_OF_CONDUCT.md CONTRIBUTING.md CREDITS INSTALL.md README.md )
|
|
|
|
src_prepare() {
|
|
# Remove failing tests. bug #904186
|
|
rm -r test-suite/coq-makefile/timing || die
|
|
|
|
default
|
|
}
|
|
|
|
src_configure() {
|
|
export CAML_LD_LIBRARY_PATH="${S}/kernel/byterun/"
|
|
|
|
dune_packages=(
|
|
coq-core
|
|
coq-stdlib
|
|
coqide-server
|
|
coq
|
|
)
|
|
use gui && dune_packages+=( coqide )
|
|
|
|
emake clean
|
|
|
|
local -a myconf=(
|
|
-prefix /usr
|
|
-libdir /usr/$(get_libdir)/coq
|
|
-mandir /usr/share/man
|
|
-docdir /usr/share/doc/${PF}
|
|
-datadir /usr/share/coq
|
|
-configdir /etc/xdg/${PN}
|
|
-native-compiler $(usex ocamlopt yes no)
|
|
)
|
|
use debug && myconf+=( -debug )
|
|
edob sh ./configure "${myconf[@]}"
|
|
}
|
|
|
|
src_compile() {
|
|
emake DUNEOPT="--display=short --profile release" VERBOSE=1 dunestrap
|
|
|
|
dune-compile ${dune_packages[@]}
|
|
|
|
use doc && emake refman-html
|
|
}
|
|
|
|
src_install() {
|
|
dune-install ${dune_packages[@]}
|
|
|
|
if use gui ; then
|
|
make_desktop_entry coqide "Coq IDE" "${EPREFIX}/usr/share/coq/coq.png"
|
|
fi
|
|
|
|
# Dune installs into /usr/<libdir>/ocaml/<coq> but
|
|
# Coq wants /usr/<libdir>/<coq> ; symlink those directories
|
|
local sym
|
|
for sym in ${dune_packages[@]} ; do
|
|
dosym $(ocamlc -where)/${sym} /usr/$(get_libdir)/${sym}
|
|
done
|
|
|
|
einstalldocs
|
|
}
|