app-editors/pluma: add 1.28.0

Signed-off-by: Ian Jordan <immoloism@gmail.com>
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

app-editors/pluma/Manifest

@@ -1 +1,2 @@
 DIST pluma-1.26.1.tar.xz 3824664 BLAKE2B e5ee5c2efeec90fb6733fac1077c870c79a386b3ab28d71a17929f144ecf9ae73ab66dc1a806504d7cb244bdd3c9ad63b7cccb5fb8f1f44b7b44a1076948a0e7 SHA512 bc4f621736d93df07fc2dc434a25c5a5acaf0d2c958eac43bd0061d4b664cae9b9eac1fffc47afa1509fd64b3c93a77ca62737428b034ca25997ebee432d5eb3
+DIST pluma-1.28.0.tar.xz 3866800 BLAKE2B 10813717b7d18a0836059a10deb67a61b00a73cf3d5b18f12a9e760b8b65053b3a82dc0ac9af898d9f2bb4d6998db536bcaef143024ae91f9035fe6e1ee72fea SHA512 8f21aabed46a70dfe8446ddf6db5cc4326782328d0b8dd3689c8b906cc8d4b746712c6b9decfa48ef028bdbb8a0b1c6a2ec43def23488ae55cfd59aafd5a691a

app-editors/pluma/pluma-1.28.0.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MATE_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{10..12} )
+inherit mate python-single-r1 virtualx
+
+DESCRIPTION="Pluma text editor for the MATE desktop"
+
+MINOR=$(($(ver_cut 2) % 2))
+if [[ ${MINOR} -eq 0 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+fi
+
+LICENSE="FDL-1.1+ GPL-2+ LGPL-2+"
+SLOT=0
+IUSE="+introspection spell test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0
+	>=dev-libs/glib-2.50:2
+	>=dev-libs/libpeas-1.2.0:0[gtk]
+	>=dev-libs/libxml2-2.5:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	>=x11-libs/gtksourceview-4.0.2:4
+	x11-libs/libICE
+	x11-libs/libX11
+	>=x11-libs/libSM-1.0
+	x11-libs/pango
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+	spell? (
+		>=app-text/enchant-1.6:=
+		>=app-text/iso-codes-0.35
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	>=mate-base/mate-desktop-1.9[introspection?]
+	virtual/libintl
+"
+DEPEND="${COMMON_DEPEND}
+	~app-text/docbook-xml-dtd-4.1.2
+	app-text/yelp-tools
+	dev-util/glib-utils
+	dev-util/gtk-doc
+	dev-build/gtk-doc-am
+	>=dev-build/libtool-2.2.6:2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+MATE_FORCE_AUTORECONF=true
+
+src_prepare() {
+	# Test require gvfs sftp fs mounted and schema's installed. Skip this one.
+	# https://github.com/mate-desktop/mate-text-editor/issues/33
+	sed -e '/+= document-saver/d' -i tests/Makefile.am || die
+
+	mate_src_prepare
+}
+
+src_configure() {
+	mate_src_configure \
+		$(use_enable introspection) \
+		$(use_enable spell) \
+		$(use_enable test tests)
+}
+
+src_test() {
+	# FIXME: This should be handled at eclass level.
+	"${EPREFIX}/${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+
+	unset DBUS_SESSION_BUS_ADDRESS
+	local -x GSETTINGS_SCHEMA_DIR="${S}/data"
+	virtx emake check
+}