net-ftp/filezilla: add 3.67.0
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
This commit is contained in:
parent
84aedc0f4f
commit
b2b65131ae
|
@ -1,2 +1,3 @@
|
|||
DIST FileZilla_3.66.4_src.tar.xz 4057952 BLAKE2B 0286e3e23cbd3d0599b4fced535d5bfd89508bc5f02d726ec082ac435590e0a3a1e1d90e0a6d51b19ce673b07c8b599ecd03e904a394f8fd9e1fc7f6167944f6 SHA512 17c0655988229bcfb056fe86bf8d6a21ea961420cc0073b3c4416c7fda999edd8dff7c6fe6b2121afad12acc4e6e525474a24a253c2e5312b74539de4232ef6b
|
||||
DIST FileZilla_3.66.5_src.tar.xz 4057892 BLAKE2B 0f44b027dd4a16fd0561659d27ff21930e461b33dc1188f5217119d102d0527496e1d38bca16959788c4cf41c43b581a4d66b1f3e8d2c4cad155cc7c6d00861a SHA512 b250e65894a3e8c8eb0eac25b3ffa5cd1348df2a38b1e6fa5eb735fff1945dbeb1fbcfe10a8188c260e9fbeaeb78322cb8aa56f6386fd39803421d01bbc8b2dd
|
||||
DIST FileZilla_3.67.0_src.tar.xz 4058264 BLAKE2B 28799d60188ed94bc80143ccabf073eced4caa9960daa2b8d7f617252355735647fe4b3776ee38eb179fdb2667fd05536a89b6c17b25d056c72e565585ddef98 SHA512 b2d4cd45f2ed7e70fbb11500a42fe0d0e51919831a35bcfb439455d03af8eb744eb25d7f7b6ea9a94c424065e4d071d9706fcf46019da829d1318c099ab8108c
|
||||
|
|
|
@ -0,0 +1,75 @@
|
|||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
WX_GTK_VER="3.2-gtk3"
|
||||
|
||||
inherit autotools flag-o-matic wxwidgets xdg
|
||||
|
||||
MY_PV="${PV/_/-}"
|
||||
MY_P="FileZilla_${MY_PV}"
|
||||
|
||||
DESCRIPTION="FTP client with lots of useful features and an intuitive interface"
|
||||
HOMEPAGE="https://filezilla-project.org/"
|
||||
SRC_URI="https://download.filezilla-project.org/client/${MY_P}_src.tar.xz"
|
||||
S="${WORKDIR}/${PN}-${MY_PV}"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="cpu_flags_x86_sse2 dbus nls test"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
# pugixml 1.7 minimal dependency is for c++11 proper configuration
|
||||
RDEPEND="
|
||||
>=dev-libs/nettle-3.1:=
|
||||
>=dev-db/sqlite-3.7
|
||||
>=dev-libs/boost-1.76.0:=
|
||||
>=dev-libs/libfilezilla-0.47.0:=
|
||||
>=dev-libs/pugixml-1.7
|
||||
>=net-libs/gnutls-3.5.7
|
||||
x11-libs/wxGTK:${WX_GTK_VER}[X]
|
||||
x11-misc/xdg-utils
|
||||
dbus? ( sys-apps/dbus )"
|
||||
DEPEND="${RDEPEND}
|
||||
test? ( >=dev-util/cppunit-1.13.0 )"
|
||||
BDEPEND="
|
||||
virtual/pkgconfig
|
||||
>=dev-build/libtool-1.4
|
||||
nls? ( >=sys-devel/gettext-0.11 )"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-3.22.1-debug.patch
|
||||
"${FILESDIR}"/${PN}-3.47.0-metainfo.patch
|
||||
"${FILESDIR}"/${PN}-3.47.0-disable-shellext_conf.patch
|
||||
"${FILESDIR}"/${PN}-3.52.2-slibtool.patch
|
||||
"${FILESDIR}"/${PN}-3.60.1-desktop.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
if use x86 && ! use cpu_flags_x86_sse2; then
|
||||
append-cppflags -D_FORCE_SOFTWARE_SHA
|
||||
fi
|
||||
setup-wxwidgets
|
||||
|
||||
local myeconfargs=(
|
||||
--disable-autoupdatecheck
|
||||
--with-pugixml=system
|
||||
$(use_enable nls locales)
|
||||
$(use_with dbus)
|
||||
)
|
||||
econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
|
||||
# no static archives
|
||||
find "${ED}" -name '*.la' -delete || die
|
||||
}
|
Loading…
Reference in New Issue