media-video/ffmpeg-chromium: add 125
Signed-off-by: Matt Jolly <kangie@gentoo.org>
This commit is contained in:
Matt Jolly
parent
efa4191b01
commit
9cc853fa4e
|
|
@ -2,3 +2,4 @@ DIST ffmpeg-chromium-120.tar.xz 10096036 BLAKE2B 8f24dfed854c713df369e6ef15bc773
|
|||
DIST ffmpeg-chromium-121.tar.xz 10128048 BLAKE2B ba8e25356b7e0820dffea1b919288ddb3d6ec56fe8d17493529ec978deae629607ff5a5857a313e478193a1fca55fa3e5256e37d57251141e1f0a892cbdcf674 SHA512 e6cef1285237673ce5851cbddf4cda77779821c247a120bf73af2b931745b2886c915a35bb2bc21a8a9c5154be9e540f8abccc3bb64e704f5b859141d0dcc2e1
|
||||
DIST ffmpeg-chromium-123.tar.xz 10323756 BLAKE2B b56afd5946513511938feeea4fd60e22fcf241a2380b36990eadf812b3517d6941156de73135efdc873704d27bc3329c71193be5132e462caaf7f2dc29e8a058 SHA512 635e1c5496d6f41fa5dd69efbe6dd335a15705dce8544fc45df440b19965caa130646d16b7c22b2b7cc0809979d28f39245fc5c208637e445b1fc1eb384da418
|
||||
DIST ffmpeg-chromium-124.tar.xz 10378648 BLAKE2B 3cb79d356e84d76a241ad81491d22d42b7a768e348d245bda00101e3967c0864e95a1dd83372e6aaf3a9130ff5ae38610fe2bd4ee8e21fc8247af4172af0683a SHA512 627d1ba81c50300e7188e8a2cc5f76ea9e81e817209631f2eecb81b7b9a0be60a12290eba16240dd0b0dce3d59550a8246be54df2035bd75a9e95ae77d67467b
|
||||
DIST ffmpeg-chromium-125.tar.xz 10372892 BLAKE2B 53b805354b55f1dfbe2341b767aaccca7efea4cced02db9090be88e89a4d2d688904ffc996c206d92a99d4eb93733b7f8cb47fd80dc43019c3bb6690903a1140 SHA512 c1b68b16a3dbd6f96e52c313b9ddf1c193ef302e5cbe7e127c511e54a4453c32c84b3df954e397d7ba834ef17fe1cba6efabfde855d3bb9e497bcde1b66c3d8d
|
||||
|
|
|
|||
|
|
@ -0,0 +1,247 @@
|
|||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit flag-o-matic toolchain-funcs
|
||||
|
||||
COMMIT=901248a373cbbe7af68fb92faf3be7d4f679150d
|
||||
DESCRIPTION="FFmpeg built specifically for codec support in Chromium-based browsers"
|
||||
HOMEPAGE="https://ffmpeg.org/"
|
||||
SRC_URI="https://deps.gentoo.zip/media-video/${P}.tar.xz"
|
||||
|
||||
LICENSE="
|
||||
!gpl? ( LGPL-2.1 )
|
||||
gpl? ( GPL-2 )
|
||||
"
|
||||
SLOT="${PV}"
|
||||
|
||||
KEYWORDS="~amd64 ~arm ~arm64"
|
||||
|
||||
# Options to use as use_enable in the foo[:bar] form.
|
||||
# This will feed configure with $(use_enable foo bar)
|
||||
# or $(use_enable foo foo) if no :bar is set.
|
||||
# foo is added to IUSE.
|
||||
FFMPEG_FLAG_MAP=(
|
||||
cpudetection:runtime-cpudetect debug
|
||||
+gpl
|
||||
vaapi vdpau vulkan
|
||||
nvenc:ffnvcodec
|
||||
# Threads; we only support pthread for now but ffmpeg supports more
|
||||
+threads:pthreads
|
||||
)
|
||||
|
||||
IUSE="
|
||||
${FFMPEG_FLAG_MAP[@]%:*}
|
||||
"
|
||||
|
||||
# Strings for CPU features in the useflag[:configure_option] form
|
||||
# if :configure_option isn't set, it will use 'useflag' as configure option
|
||||
ARM_CPU_FEATURES=(
|
||||
cpu_flags_arm_thumb:armv5te
|
||||
cpu_flags_arm_v6:armv6
|
||||
cpu_flags_arm_thumb2:armv6t2
|
||||
cpu_flags_arm_neon:neon
|
||||
cpu_flags_arm_vfp:vfp
|
||||
cpu_flags_arm_vfpv3:vfpv3
|
||||
cpu_flags_arm_v8:armv8
|
||||
cpu_flags_arm_asimddp:dotprod
|
||||
cpu_flags_arm_i8mm:i8mm
|
||||
)
|
||||
ARM_CPU_REQUIRED_USE="
|
||||
arm64? ( cpu_flags_arm_v8 )
|
||||
cpu_flags_arm_v8? ( cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
|
||||
cpu_flags_arm_neon? (
|
||||
cpu_flags_arm_vfp
|
||||
arm? ( cpu_flags_arm_thumb2 )
|
||||
)
|
||||
cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
|
||||
cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
|
||||
cpu_flags_arm_v6? (
|
||||
arm? ( cpu_flags_arm_thumb )
|
||||
)
|
||||
"
|
||||
X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx
|
||||
mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
|
||||
X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
|
||||
X86_CPU_REQUIRED_USE="
|
||||
cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
|
||||
cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
|
||||
cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
|
||||
cpu_flags_x86_xop? ( cpu_flags_x86_avx )
|
||||
cpu_flags_x86_avx? ( cpu_flags_x86_sse4_2 )
|
||||
cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
|
||||
cpu_flags_x86_sse4_2? ( cpu_flags_x86_sse4_1 )
|
||||
cpu_flags_x86_sse4_1? ( cpu_flags_x86_ssse3 )
|
||||
cpu_flags_x86_ssse3? ( cpu_flags_x86_sse3 )
|
||||
cpu_flags_x86_sse3? ( cpu_flags_x86_sse2 )
|
||||
cpu_flags_x86_sse2? ( cpu_flags_x86_sse )
|
||||
cpu_flags_x86_sse? ( cpu_flags_x86_mmxext )
|
||||
cpu_flags_x86_mmxext? ( cpu_flags_x86_mmx )
|
||||
cpu_flags_x86_3dnowext? ( cpu_flags_x86_3dnow )
|
||||
cpu_flags_x86_3dnow? ( cpu_flags_x86_mmx )
|
||||
"
|
||||
|
||||
CPU_FEATURES_MAP=(
|
||||
${ARM_CPU_FEATURES[@]}
|
||||
${X86_CPU_FEATURES[@]}
|
||||
)
|
||||
IUSE="${IUSE}
|
||||
${CPU_FEATURES_MAP[@]%:*}"
|
||||
|
||||
CPU_REQUIRED_USE="
|
||||
${ARM_CPU_REQUIRED_USE}
|
||||
${X86_CPU_REQUIRED_USE}
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
>=media-libs/opus-1.0.2-r2
|
||||
vaapi? ( >=media-libs/libva-1.2.1-r1:0= )
|
||||
nvenc? ( >=media-libs/nv-codec-headers-11.1.5.3 )
|
||||
vdpau? ( >=x11-libs/libvdpau-0.7 )
|
||||
vulkan? ( >=media-libs/vulkan-loader-1.3.255:= )
|
||||
"
|
||||
|
||||
DEPEND="${RDEPEND}
|
||||
vulkan? ( >=dev-util/vulkan-headers-1.3.255 )
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-build/make-3.81
|
||||
virtual/pkgconfig
|
||||
cpu_flags_x86_mmx? ( || ( >=dev-lang/nasm-2.13 >=dev-lang/yasm-1.3 ) )
|
||||
"
|
||||
|
||||
REQUIRED_USE="
|
||||
${CPU_REQUIRED_USE}"
|
||||
RESTRICT="
|
||||
test
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-120.patch
|
||||
"${FILESDIR}"/chromium.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
export revision=git-N-g${COMMIT:0:10}
|
||||
default
|
||||
|
||||
# -fdiagnostics-color=auto gets appended after user flags which
|
||||
# will ignore user's preference.
|
||||
sed -i -e '/check_cflags -fdiagnostics-color=auto/d' configure || die
|
||||
|
||||
echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local myconf=( )
|
||||
|
||||
# Bug #918997. Will probably be fixed upstream in the next release.
|
||||
use vulkan && append-ldflags -Wl,-z,muldefs
|
||||
|
||||
# bug 842201
|
||||
use ia64 && tc-is-gcc && append-flags \
|
||||
-fno-tree-ccp \
|
||||
-fno-tree-dominator-opts \
|
||||
-fno-tree-fre \
|
||||
-fno-code-hoisting \
|
||||
-fno-tree-pre \
|
||||
-fno-tree-vrp
|
||||
|
||||
local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
|
||||
|
||||
for i in "${ffuse[@]#+}" ; do
|
||||
myconf+=( $(use_enable ${i%:*} ${i#*:}) )
|
||||
done
|
||||
|
||||
# CPU features
|
||||
for i in "${CPU_FEATURES_MAP[@]}" ; do
|
||||
use ${i%:*} || myconf+=( --disable-${i#*:} )
|
||||
done
|
||||
|
||||
# Try to get cpu type based on CFLAGS.
|
||||
# Bug #172723
|
||||
# We need to do this so that features of that CPU will be better used
|
||||
# If they contain an unknown CPU it will not hurt since ffmpeg's configure
|
||||
# will just ignore it.
|
||||
for i in $(get-flag mcpu) $(get-flag march) ; do
|
||||
[[ ${i} = native ]] && i="host" # bug #273421
|
||||
myconf+=( --cpu=${i} )
|
||||
break
|
||||
done
|
||||
|
||||
# LTO support, bug #566282, bug #754654, bug #772854
|
||||
if [[ ${ABI} != x86 ]] && tc-is-lto; then
|
||||
# Respect -flto value, e.g -flto=thin
|
||||
local v="$(get-flag flto)"
|
||||
[[ -n ${v} ]] && myconf+=( "--enable-lto=${v}" ) || myconf+=( "--enable-lto" )
|
||||
fi
|
||||
filter-lto
|
||||
|
||||
# Mandatory configuration
|
||||
myconf=(
|
||||
--disable-stripping
|
||||
# This is only for hardcoded cflags; those are used in configure checks that may
|
||||
# interfere with proper detections, bug #671746 and bug #645778
|
||||
# We use optflags, so that overrides them anyway.
|
||||
--disable-optimizations
|
||||
--disable-libcelt # bug #664158
|
||||
"${myconf[@]}"
|
||||
)
|
||||
|
||||
# cross compile support
|
||||
if tc-is-cross-compiler ; then
|
||||
myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
|
||||
case ${CHOST} in
|
||||
*mingw32*)
|
||||
myconf+=( --target-os=mingw32 )
|
||||
;;
|
||||
*linux*)
|
||||
myconf+=( --target-os=linux )
|
||||
;;
|
||||
esac
|
||||
fi
|
||||
|
||||
# Use --extra-libs if needed for LIBS
|
||||
set -- "${S}/configure" \
|
||||
--prefix="${EPREFIX}/usr" \
|
||||
--libdir="${EPREFIX}/usr/$(get_libdir)" \
|
||||
--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
|
||||
--cc="$(tc-getCC)" \
|
||||
--cxx="$(tc-getCXX)" \
|
||||
--ar="$(tc-getAR)" \
|
||||
--nm="$(tc-getNM)" \
|
||||
--strip="$(tc-getSTRIP)" \
|
||||
--ranlib="$(tc-getRANLIB)" \
|
||||
--pkg-config="$(tc-getPKG_CONFIG)" \
|
||||
--optflags="${CFLAGS}" \
|
||||
--disable-all \
|
||||
--disable-autodetect \
|
||||
--disable-error-resilience \
|
||||
--disable-everything \
|
||||
--disable-faan \
|
||||
--disable-iconv \
|
||||
--disable-network \
|
||||
--enable-avcodec \
|
||||
--enable-avformat \
|
||||
--enable-avutil \
|
||||
--enable-libopus \
|
||||
--enable-decoder=aac,flac,h264,libopus,mp3,pcm_alaw,pcm_f32le,pcm_mulaw,pcm_s16be,pcm_s16le,pcm_s24be,pcm_s24le,pcm_s32le,pcm_u8,theora,vorbis,vp8 \
|
||||
--enable-demuxer=aac,flac,matroska,mov,mp3,ogg,wav \
|
||||
--enable-parser=aac,flac,h264,mpegaudio,opus,vorbis,vp3,vp8,vp9 \
|
||||
--enable-pic \
|
||||
--enable-static \
|
||||
"${myconf[@]}" \
|
||||
${EXTRA_FFMPEG_CONF}
|
||||
|
||||
echo "${@}"
|
||||
"${@}" || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
emake V=1 libffmpeg
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake V=1 DESTDIR="${D}" install-libffmpeg
|
||||
}
|
||||
Loading…
Reference in New Issue