x11-libs/libxkbcommon: Version bump to 1.7.0
Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
parent
b8fd60bd72
commit
9c95b044e7
|
@ -1 +1,2 @@
|
|||
DIST libxkbcommon-1.6.0.tar.xz 510456 BLAKE2B ffd373161f12ea6448a9206f57710355ab65b81ebab5dce74e4dfcee1bdc9175406fc434560648f5933b83cac163099c8564c3add6f51d34856def39ab077850 SHA512 4f93225eada1c5d0806bbc01f72d82d72729f4580ade963ff6a386711c9b2232aae5213c8488abf01c3b81f0e1fdb7f4d8a4d3786113ccc134251ff164c4be5c
|
||||
DIST libxkbcommon-1.7.0.tar.xz 534312 BLAKE2B b85cd8a78fce3c624e0c64c26a37b6d99bb8b8f3de489c6909826f53bdb6d33842f7ffcf955f6a9a8eb57cad53fc9756bd15d05aeb813b0f92985827243949a8 SHA512 4b74a9f3f63e2ebc1cbdcaa963c70362e55fa527e1d89b6a1fd30d7a84a8b60c1b3dc99bcfbde85aa31890e0b2f62f0bad3c8ff8340fe6a930ee662b33448ba5
|
||||
|
|
|
@ -0,0 +1,71 @@
|
|||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
if [[ ${PV} = *9999* ]]; then
|
||||
GIT_ECLASS="git-r3"
|
||||
EGIT_REPO_URI="https://github.com/xkbcommon/${PN}"
|
||||
else
|
||||
SRC_URI="https://xkbcommon.org/download/${P}.tar.xz"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
|
||||
fi
|
||||
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
|
||||
inherit bash-completion-r1 meson-multilib ${GIT_ECLASS} python-any-r1 virtualx
|
||||
|
||||
DESCRIPTION="Keymap handling library for toolkits and window systems"
|
||||
HOMEPAGE="https://xkbcommon.org/ https://github.com/xkbcommon/libxkbcommon/"
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
|
||||
IUSE="doc static-libs test tools wayland X"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
BDEPEND="
|
||||
app-alternatives/yacc
|
||||
doc? ( app-text/doxygen[dot] )
|
||||
test? ( ${PYTHON_DEPS} )
|
||||
tools? ( wayland? ( dev-util/wayland-scanner ) )
|
||||
"
|
||||
RDEPEND="
|
||||
X? ( >=x11-libs/libxcb-1.10:=[${MULTILIB_USEDEP}] )
|
||||
tools? ( wayland? ( >=dev-libs/wayland-1.2.0[${MULTILIB_USEDEP}] ) )
|
||||
dev-libs/libxml2[${MULTILIB_USEDEP}]
|
||||
x11-misc/compose-tables
|
||||
x11-misc/xkeyboard-config
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
X? ( x11-base/xorg-proto )
|
||||
tools? ( wayland? ( >=dev-libs/wayland-protocols-1.12 ) )
|
||||
"
|
||||
|
||||
pkg_setup() {
|
||||
if use test; then
|
||||
python-any-r1_pkg_setup
|
||||
fi
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
local emesonargs=(
|
||||
-Ddefault_library="$(usex static-libs both shared)"
|
||||
-Dxkb-config-root="${EPREFIX}/usr/share/X11/xkb"
|
||||
-Dbash-completion-path="$(get_bashcompdir)"
|
||||
$(meson_native_use_bool tools enable-tools)
|
||||
$(meson_use X enable-x11)
|
||||
$(meson_native_use_bool doc enable-docs)
|
||||
$(meson_use wayland enable-wayland)
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
virtx meson_src_test
|
||||
}
|
||||
|
||||
multilib_src_install_all() {
|
||||
if use doc; then
|
||||
mv "${ED}"/usr/share/doc/{${PN},${P}} || die
|
||||
fi
|
||||
}
|
Loading…
Reference in New Issue