mate-base/caja: add 1.28.0

Signed-off-by: Ian Jordan <immoloism@gmail.com>
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

mate-base/caja/Manifest

@@ -1 +1,2 @@
 DIST caja-1.26.3.tar.xz 5276276 BLAKE2B d9347986939433bf3b28b58ab8412579caa5cafddc72880a45dcffef75a5431cc81741a4f7006f1183c2b74cbae673db69ed8191616bd85c262bd07204601efd SHA512 6f17d46de77c552f68c77e0b6a0c388a7fe353ddd5ea5376685aec209f301b5a74a76b1af4c2324f41838ff7251acffa3bd119cf2462a8b8b45ef1b88df4c83c
+DIST caja-1.28.0.tar.xz 5332720 BLAKE2B 3fd97d20081fc1b8dde845f899f13270b164e3fd7116f32d8f5248e27f75e49e0668cb928417e74abac908a93a7fb6a81927c43443dc752e30d13fdec6b7ab09 SHA512 059f88d4fc8a48483fe180645c75fefd0941ac8e4b2aadd16ddc8a89c7505081ce7d8a063d2c2a3c224f4fb279125561a83150e4d2142f718c3a54764cf8fbc2

mate-base/caja/caja-1.28.0.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+MINOR=$(($(ver_cut 2) % 2))
+if [[ ${MINOR} -eq 0 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+fi
+
+DESCRIPTION="Caja file manager for the MATE desktop"
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+
+IUSE="+introspection +mate nls xmp"
+
+COMMON_DEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	>=dev-libs/glib-2.58.1:2
+	>=dev-libs/libxml2-2.4.7:2
+	gnome-base/dconf
+	>=gnome-base/gvfs-1.10.1:0[udisks]
+	>=mate-base/mate-desktop-1.17.3:0
+	>=media-libs/libexif-0.6.14:0
+	virtual/libintl
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.36.5:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	>=x11-libs/libnotify-0.7.0:0
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXrender
+	>=x11-libs/pango-1.1.2
+	introspection? ( >=dev-libs/gobject-introspection-0.6.4:= )
+	xmp? ( >=media-libs/exempi-1.99.5:2= )
+"
+
+BDEPEND="${COMMON_DEPEND}
+	>=dev-lang/perl-5:=
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gtk-doc
+	dev-build/gtk-doc-am
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+PDEPEND="mate? ( >=x11-themes/mate-icon-theme-${MATE_BRANCH} )"
+
+# TODO: Test fails because Caja is not merged yet:
+# GLib-GIO-ERROR **: Settings schema 'org.mate.caja.preferences' is not installed
+RESTRICT="test"
+
+src_prepare() {
+	# Remove unnecessary CFLAGS.
+	sed -i -e 's:-DG.*DISABLE_DEPRECATED::g' \
+		configure.ac eel/Makefile.am || die
+
+	mate_src_prepare
+}
+
+src_configure() {
+	mate_src_configure \
+		--disable-update-mimedb \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable xmp)
+}
+
+src_test() {
+	unset SESSION_MANAGER
+	unset DBUS_SESSION_BUS_ADDRESS
+
+	Xemake check || die "Test phase failed"
+}
+
+pkg_postinst() {
+	mate_pkg_postinst
+
+	elog "Caja can use gstreamer to preview audio files. Just make sure"
+	elog "to have the necessary plugins available to play the media type you"
+	elog "want to preview."
+}