gui-apps/foot: add 1.17.1
Signed-off-by: Arsen Arsenović <arsen@gentoo.org>
This commit is contained in:
parent
1f56be9120
commit
98155cf839
|
@ -1,2 +1,3 @@
|
|||
DIST foot-1.16.2_20240120.tar.gz 529312 BLAKE2B edb4f0449effbc441ef5f0bdb5a99369633510826b3a129ff9897135df02c7e81ceea45facf0ce20b8b97bd878947426006722b6468eaabd02046b78ab2d8775 SHA512 1cdace64a21f155b440b17ad0a4cdd9150b8f4f44afdc3ff92d1dddc4c222fb9353a74ec4416c90753c70372d9f0e6ef762d00d6de4190e226621dccfc82ee1d
|
||||
DIST foot-1.17.0.tar.gz 543481 BLAKE2B 4af1665450d7d09d80502b74aa7b5be0c063f3df93aa67c4b2d1da5e69a5148db856436ffbc5868af93980e92145912da6bfcf27a3e81bf953e0e094193f5955 SHA512 4d24575c94ac5429b21134a21dd8b03d232d36798345fac3102b8a58de2acd951f6c1b4527085456072c3a0816d3fcf60210ec2004d84484b26bba22f44fbd89
|
||||
DIST foot-1.17.1.tar.gz 546745 BLAKE2B 5cb0b6dd323ce3f67dfdb47e4f06169327c95b6c5c06495f0f6a743a409684a5181970e8ac0141a857b3784c0f6f0f0647ce7db19bd99f1a0c1a0c8d846700c1 SHA512 b77d8198c504a337484ace06bc931998a70a753869c099bcab13dba3df629fd219d6bc23f22157b202333b2d5876f6030d9eeae77f1735e6983ab1c96aa8ca23
|
||||
|
|
|
@ -0,0 +1,75 @@
|
|||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit meson xdg systemd
|
||||
|
||||
DESCRIPTION="Fast, lightweight and minimalistic Wayland terminal emulator"
|
||||
HOMEPAGE="https://codeberg.org/dnkl/foot"
|
||||
SRC_URI="
|
||||
https://codeberg.org/dnkl/foot/releases/download/${PV}/${P}.tar.gz
|
||||
"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~ppc64"
|
||||
IUSE="+grapheme-clustering test"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
COMMON_DEPEND="
|
||||
dev-libs/wayland
|
||||
media-libs/fcft
|
||||
media-libs/fontconfig
|
||||
x11-libs/libxkbcommon
|
||||
x11-libs/pixman
|
||||
grapheme-clustering? (
|
||||
dev-libs/libutf8proc:=
|
||||
media-libs/fcft[harfbuzz]
|
||||
)
|
||||
"
|
||||
DEPEND="
|
||||
${COMMON_DEPEND}
|
||||
>=dev-libs/tllist-1.1.0
|
||||
>=dev-libs/wayland-protocols-1.32
|
||||
"
|
||||
RDEPEND="
|
||||
${COMMON_DEPEND}
|
||||
|| (
|
||||
>=sys-libs/ncurses-6.3[-minimal]
|
||||
~gui-apps/foot-terminfo-${PV}
|
||||
)
|
||||
"
|
||||
BDEPEND="
|
||||
app-text/scdoc
|
||||
dev-util/wayland-scanner
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
# disable the systemd dep, we install the unit file manually
|
||||
sed -i "s/systemd', required: false)$/', required: false)/" "${S}"/meson.build || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
$(meson_feature grapheme-clustering)
|
||||
$(meson_use test tests)
|
||||
-Dthemes=true
|
||||
-Dime=true
|
||||
-Dterminfo=disabled
|
||||
)
|
||||
meson_src_configure
|
||||
|
||||
sed 's|@bindir@|/usr/bin|g' "${S}"/foot-server.service.in > foot-server.service || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local DOCS=( CHANGELOG.md README.md LICENSE )
|
||||
meson_src_install
|
||||
|
||||
# foot unconditionally installs CHANGELOG.md, README.md and LICENSE.
|
||||
# we handle this via DOCS and dodoc instead.
|
||||
rm -r "${ED}/usr/share/doc/${PN}" || die
|
||||
systemd_douserunit foot-server.service "${S}"/foot-server.socket
|
||||
}
|
Loading…
Reference in New Issue