xfce-base/xfce4-session: Bump to 4.17.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfce4-session/Manifest

@@ -1 +1,2 @@
 DIST xfce4-session-4.16.0.tar.bz2 875504 BLAKE2B 8e06e1ff378593b90c3c600bd5aabb3ea9ba9e58854ed615d39009595be4b71c5f77359e4249a93f44aa67795e2d4bf658b83d9c1d445304764eee655ed1f9e9 SHA512 fd74b24d0c2762b5a99883b62ca9447c3683e42e9e39193d0f60e02b8c1ad77a3dfff4df6f3b3c345d8ea3d4c4ef93485e9b5586862bab85d4b37110d3400fad
+DIST xfce4-session-4.17.0.tar.bz2 878866 BLAKE2B e84165848e33285c33d692076d9494b47ff481bbd60e8eaa18f8a04ecfc646da6fb9fbcd8f85eb1f5f2f0bfbbc90d20c8db5648211730b7d6ef7870c5a0805e2 SHA512 89140f75c5751a9e55c5e9931fcac82541dcba09e92cb6591b929e2cc919bd09fc8c72f6681ad584cc2097d18584e6743dfd2d72e08d1432e7388432b65a88a7

xfce-base/xfce4-session/xfce4-session-4.17.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-session/start
+	https://gitlab.xfce.org/xfce/xfce4-session
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls policykit +xscreensaver"
+
+DEPEND="
+	>=dev-libs/glib-2.50
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libSM
+	x11-libs/libwnck:3
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.15.2:=
+	>=xfce-base/libxfce4ui-4.15.1:=
+	>=xfce-base/xfconf-4.12:=
+	policykit? ( >=sys-auth/polkit-0.102 )
+"
+RDEPEND="
+	${DEPEND}
+	x11-apps/iceauth
+	x11-apps/xrdb
+	nls? ( x11-misc/xdg-user-dirs )
+	xscreensaver? (
+		|| (
+			xfce-extra/xfce4-screensaver
+			>=x11-misc/xscreensaver-5.26
+			x11-misc/light-locker
+		)
+	)"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		--with-xsession-prefix="${EPREFIX}"/usr
+		ICEAUTH="${EPREFIX}"/usr/bin/iceauth
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+
+	exeinto /etc/X11/Sessions
+	newexe - Xfce4 <<-EOF
+		startxfce4
+	EOF
+	dosym Xfce4 /etc/X11/Sessions/Xfce
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}