kde-misc/tellico: add 3.5.4
See also: https://tellico-project.org/tellico-3-5-4-released/ https://mail.kde.org/pipermail/kde-announce-apps/2024-March/005794.html Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
parent
3aac181fe6
commit
87dc94e84f
|
@ -1 +1,2 @@
|
|||
DIST tellico-3.5.3.tar.xz 6767436 BLAKE2B ccfbb60635201def188aba93a861301384f301d28c9211215d5ba08803653f45421a84e07f5beafe5969f713b0cd8e357a3d0573fd1c2fd776655c801018da88 SHA512 158ea7a8a4cc47435df0e9f7e439f489e886735098133fdbaef8de2de46ecfd3245ab312ab62f3020a3b4665eb68d9e6b98a3cfd121820233b4762361bef89ea
|
||||
DIST tellico-3.5.4.tar.xz 6768904 BLAKE2B 61242fa43287f8e37990040f1a94df631a3596527a4d2e3d7b61c7c34e50005ba2529acdde6d44acffef6127bfd634e86bd5d66c21e4623496daf31d80b6fbe3 SHA512 b38405feb59107c4022158fee5a0435b61ea5e66c9265f930d1cb3be22d66e972b107f2f7eddb0cdf07f044f4d1428e2df879aaa67270045c8c30dd678dd83b9
|
||||
|
|
|
@ -0,0 +1,89 @@
|
|||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_HANDBOOK="forceoptional"
|
||||
ECM_TEST="forceoptional"
|
||||
inherit ecm kde.org
|
||||
|
||||
DESCRIPTION="Collection manager based on KDE Frameworks"
|
||||
HOMEPAGE="https://tellico-project.org/"
|
||||
|
||||
if [[ ${KDE_BUILD_TYPE} != live ]]; then
|
||||
SRC_URI="https://tellico-project.org/files/${P}.tar.xz"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
LICENSE="|| ( GPL-2 GPL-3 )"
|
||||
SLOT="5"
|
||||
IUSE="bibtex cddb discid pdf scanner semantic-desktop taglib v4l xmp yaz"
|
||||
|
||||
# tests need network access
|
||||
RESTRICT="test"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libxml2
|
||||
dev-libs/libxslt
|
||||
dev-qt/qtcharts:5
|
||||
dev-qt/qtdbus:5
|
||||
dev-qt/qtgui:5
|
||||
dev-qt/qtnetwork:5
|
||||
dev-qt/qtprintsupport:5
|
||||
dev-qt/qtwebengine:5[widgets]
|
||||
dev-qt/qtwidgets:5
|
||||
dev-qt/qtxml:5
|
||||
kde-frameworks/karchive:5
|
||||
kde-frameworks/kcodecs:5
|
||||
kde-frameworks/kcompletion:5
|
||||
kde-frameworks/kconfig:5
|
||||
kde-frameworks/kconfigwidgets:5
|
||||
kde-frameworks/kcoreaddons:5
|
||||
kde-frameworks/kcrash:5
|
||||
kde-frameworks/kguiaddons:5
|
||||
kde-frameworks/kiconthemes:5
|
||||
kde-frameworks/kitemmodels:5
|
||||
kde-frameworks/ki18n:5
|
||||
kde-frameworks/kjobwidgets:5
|
||||
kde-frameworks/kio:5
|
||||
kde-frameworks/knewstuff:5
|
||||
kde-frameworks/kparts:5
|
||||
kde-frameworks/kservice:5
|
||||
kde-frameworks/ktextwidgets:5
|
||||
kde-frameworks/kwallet:5
|
||||
kde-frameworks/kwidgetsaddons:5
|
||||
kde-frameworks/kwindowsystem:5
|
||||
kde-frameworks/kxmlgui:5
|
||||
kde-frameworks/solid:5
|
||||
kde-frameworks/sonnet:5
|
||||
bibtex? ( >=dev-perl/Text-BibTeX-0.780.0-r1 )
|
||||
cddb? ( kde-apps/libkcddb:5 )
|
||||
discid? ( dev-libs/libcdio:= )
|
||||
pdf? ( app-text/poppler[qt5] )
|
||||
scanner? ( kde-apps/libksane:5 )
|
||||
semantic-desktop? ( kde-frameworks/kfilemetadata:5 )
|
||||
taglib? ( >=media-libs/taglib-1.5 )
|
||||
v4l? ( >=media-libs/libv4l-0.8.3 )
|
||||
xmp? ( >=media-libs/exempi-2:= )
|
||||
yaz? ( >=dev-libs/yaz-2:0= )
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
BDEPEND="sys-devel/gettext"
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DCMAKE_DISABLE_FIND_PACKAGE_Csv=ON
|
||||
-DENABLE_BTPARSE=$(usex bibtex)
|
||||
$(cmake_use_find_package cddb KF5Cddb)
|
||||
$(cmake_use_find_package discid CDIO)
|
||||
$(cmake_use_find_package pdf Poppler)
|
||||
$(cmake_use_find_package scanner KF5Sane)
|
||||
$(cmake_use_find_package semantic-desktop KF5FileMetaData)
|
||||
$(cmake_use_find_package taglib Taglib)
|
||||
-DENABLE_WEBCAM=$(usex v4l)
|
||||
$(cmake_use_find_package xmp Exempi)
|
||||
$(cmake_use_find_package yaz Yaz)
|
||||
)
|
||||
|
||||
ecm_src_configure
|
||||
}
|
Loading…
Reference in New Issue