app-editors/kile: add 2.9.94

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

app-editors/kile/Manifest

@@ -1 +1,2 @@
 DIST kile-2.9.93_p20221123-1ca67389.tar.gz 9507069 BLAKE2B 61770aeafe6604b8a45ae9e49fc79a375815fce5e11a189aef962172f60d0182984f6908a626cb95b493f1fe894958ec0816420096a12efbd03233114e0a5dcc SHA512 ed16cfb7cee3d08ad21fabecd5536981c68431261c02f66cc979f5f01229fa33c192c33f5d1ef78d61c37e643ab313eb432fd580aea61f5a918d3de76d2dcadc
+DIST kile-2.9.94.tar.bz2 7505095 BLAKE2B b42d7237f612f2d6017bdde3cfea29a74b4756b96cc707b178217e0ab5b599d86b2ffc8e0283fcd6e351746151738bcbff65183b93a347c6fb11250233b7fe5a SHA512 4638e81374243a8b2716183bf28cec02bcb455f2b1a9295e7e04f20833b77c962bddfeb81e527606209c338862af48a38d9f6009a9f7b96aac37f874ae3f725c

app-editors/kile/kile-2.9.94.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KDE_ORG_CATEGORY="office"
+KFMIN=6.0.0
+QTMIN=6.6.2
+MY_P=${P/_beta/b}
+inherit ecm kde.org
+
+DESCRIPTION="Latex Editor and TeX shell based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kile/ https://kile.sourceforge.io/"
+
+if [[ ${KDE_BUILD_TYPE} == release ]]; then
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="FDL-1.2 GPL-2"
+SLOT="0"
+IUSE="+pdf +png"
+
+DEPEND="
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	kde-apps/okular:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdoctools-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	pdf? ( >=app-text/poppler-23.12.0[qt6] )
+"
+RDEPEND="${DEPEND}
+	!${CATEGORY}/${PN}:5
+	kde-apps/konsole:6
+	kde-apps/okular:6[pdf?]
+	virtual/latex-base
+	virtual/tex-base
+	pdf? (
+		app-text/ghostscript-gpl
+		app-text/texlive-core
+	)
+	png? (
+		app-text/dvipng
+		virtual/imagemagick-tools[png?]
+	)
+"
+
+DOCS=( kile-remote-control.txt )
+
+PATCHES=( "${FILESDIR}/${PN}-2.9.93_p20221123-cmake.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package pdf Poppler)
+	)
+	ecm_src_configure
+}

profiles/package.mask

@@ -594,6 +594,7 @@ sci-libs/mpir
 =kde-plasma/print-manager-23.08.5-r100
 ~kde-misc/kio-fuse-5.1.0
 ~kde-misc/plasma-pass-1.2.2
+~app-editors/kile-2.9.94
 ~dev-db/futuresql-0.1.1
 ~dev-libs/appstream-1.0.2
 ~dev-libs/kdiagram-3.0.1