net-im/mattermost-desktop-bin: add 5.4.0_rc1

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

net-im/mattermost-desktop-bin/Manifest

@@ -1,2 +1,4 @@
 DIST mattermost-desktop-5.3.1-linux-arm64.tar.gz 99877249 BLAKE2B a519510d2d5e09b053012e10620fcc47418abab6ebb1276a3f4ecdc624a5f29852e61447954f125a23ec1c1e34cda17259ed44fa4381048ed105d4a12ed1db69 SHA512 6b047a5a7160957a38201e05df2cfdd395de7d25db2128e5b9f29cbcfb63a3733f4633f323973c334a705747c92be4f79c0ac94caf80af3dda258d8a24a2b3b0
 DIST mattermost-desktop-5.3.1-linux-x64.tar.gz 99666315 BLAKE2B 5d330cc70404e969c9a7e1ed65c0ad6361453c331639e20443ac25d9c7df179667bf55c737b4392eb738ae58cc708d6542ff1de9a53411381321dbdcafebf725 SHA512 94959fbd20598c7c13838e5ce8c95ed71756d4f59a377dd98662d23f70f8f600d35f8ac027d2fd0da63ae72af930814322cc57a1be1c43389e90cd58ad3b5cfb
+DIST mattermost-desktop-5.4.0-rc.1-linux-arm64.tar.gz 98203300 BLAKE2B 7e012c44e2270846e52d06608f6a1bc1ae5cd3996213eed0595dc6ecb4bd48eb0c4d67743f20b546d05e632876423514d38975ecafa462ca473c8fdd9a1715a4 SHA512 721376179f5a7ee93039c058427e34002480d27b3ec5de01f434c4f299e11ffb8d92299882cd744ffa8653a889b4a598e88c061670608f998a452226abb8a1ea
+DIST mattermost-desktop-5.4.0-rc.1-linux-x64.tar.gz 97476728 BLAKE2B 23cc225ff1456f0ec256fc4606fa8bcd63d35b45ad9eb1543f58662a01a03e963b1aacfae0faf8b2c96cd32c2e0f359cca3394aab3086ddcf3e7b996db5398e8 SHA512 232ca64f884ad756c45063fd7b4c8964195ca0267387b02a8c0055edb8552cf6ff77c303b17b58affacc3ff370939f979b4a483e23d0b269179fd8e23ca43981

net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.4.0_rc1.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN%-*}"
+MY_PV="${PV/_rc/-rc.}"
+
+inherit desktop xdg
+
+DESCRIPTION="Mattermost Desktop application"
+HOMEPAGE="https://mattermost.com/"
+
+SRC_URI="
+	amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
+	arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
+"
+
+LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+# Starting with 5.2.0 upstream dropped x86 for their binary release #879519
+if [[ ${PV} != *rc* ]]; then
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2[X]
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gtk+:3[X]
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango
+"
+
+QA_PREBUILT="
+	opt/mattermost-desktop/mattermost-desktop
+	opt/mattermost-desktop/libnode.so
+	opt/mattermost-desktop/libffmpeg.so
+	opt/mattermost-desktop/libGLESv2.so
+	opt/mattermost-desktop/libEGL.so
+	opt/mattermost-desktop/libvk_swiftshader.so
+	opt/mattermost-desktop/libvulkan.so.1
+	opt/mattermost-desktop/resources/*
+"
+
+DOCS=(
+	NOTICE.txt
+)
+
+S="${WORKDIR}"
+
+src_install() {
+	if use amd64; then
+		cd mattermost-desktop-${MY_PV}-linux-x64 || die
+	elif use arm64; then
+		cd mattermost-desktop-${MY_PV}-linux-arm64 || die
+	fi
+	newicon app_icon.png ${MY_PN}.png
+
+	insinto "/opt/${MY_PN}/locales"
+	doins locales/*.pak
+
+	insinto "/opt/${MY_PN}/resources"
+	doins -r resources/*.asar*
+
+	insinto "/opt/${MY_PN}"
+	doins *.pak *.bin *.dat
+	exeinto "/opt/${MY_PN}"
+	doexe *.so *.so.* "${MY_PN}"
+
+	dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	make_desktop_entry "${MY_PN} --enable-features=WaylandWindowDecorations --ozone-platform-hint=auto" \
+		Mattermost "${MY_PN}"
+
+	einstalldocs
+}