dev-tcltk/tktreectrl: EAPI8 bump, use https

Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>

Bug: https://bugs.gentoo.org/828839
Closes: https://bugs.gentoo.org/906870
Closes: https://github.com/gentoo/gentoo/pull/35391
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

dev-tcltk/tktreectrl/tktreectrl-2.4.1-r1.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit virtualx
+
+DESCRIPTION="Flexible listbox widget for Tk"
+HOMEPAGE="https://tktreectrl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="tcltk"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug shellicon threads"
+
+RDEPEND=">=dev-lang/tk-8.4:0="
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/2.2.9-as-needed.patch )
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	stat64 # used to test for Large File Support
+)
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable threads)
+		$(use_enable shellicon)
+		$(use_enable amd64 64bit)
+		$(use_enable debug symbols)
+		--with-x
+		--enable-shared
+	)
+
+	econf ${myeconfargs[@]}
+}
+
+src_test() {
+	virtx emake test
+}
+
+src_install() {
+	default
+	mv \
+		"${ED}"/usr/lib*/treectrl${PV}/htmldoc \
+		"${ED}"/usr/share/doc/${PF}/ || die
+}