media-radio/tucnak: add 4.58
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>
This commit is contained in:
parent
bc91ef1b6d
commit
2cf427e952
|
@ -1 +1,2 @@
|
|||
DIST tucnak-4.55.tar.gz 6817952 BLAKE2B 860b4718f575cc2e1116d14a95ab190dc479d37732c40a8dc5c32e04a3c7dc11cefc61074952d4d285011f91c13d6f9707734f9047dca883967d2b1a6b996bcd SHA512 10b558ce4137a114c59cdff402a6696b64771c6486f7d0c2ade088cdd028c189e5aa1c2b0832b7d7ae934774fc2329ea6915d920b27d25f2eb8c92ad37c3777a
|
||||
DIST tucnak-4.58.tar.gz 6817845 BLAKE2B f1530aa83f99bd81de89bef74f0a17abb18e3326961e95e3f5b708dcc83640f6ac7249092381290f4c683f2e3078aff75f10d54e9dc75136644c384d2628b27c SHA512 5744d11cb04a7dcfeb0b33356189e46a4c43fb21529a7dc59be5ade7f293c6d9cc72b4936c0b95c7eb15e044fc04515faf5b4ed6f4b610f4d8a018e53033978c
|
||||
|
|
|
@ -0,0 +1,68 @@
|
|||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
inherit autotools flag-o-matic
|
||||
|
||||
DESCRIPTION="Amateur Radio VHF Contest Logbook"
|
||||
HOMEPAGE="http://tucnak.nagano.cz"
|
||||
SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
IUSE="alsa fftw gpm hamlib suid"
|
||||
|
||||
RDEPEND="dev-libs/glib:2
|
||||
~dev-libs/libzia-4.58
|
||||
media-libs/libsndfile
|
||||
media-libs/libsdl2
|
||||
alsa? ( media-libs/alsa-lib )
|
||||
fftw? ( sci-libs/fftw:3.0 )
|
||||
gpm? ( sys-libs/gpm )
|
||||
hamlib? ( media-libs/hamlib:= )"
|
||||
DEPEND="${RDEPEND}
|
||||
virtual/pkgconfig"
|
||||
|
||||
src_prepare() {
|
||||
eapply_user
|
||||
# fix destop file
|
||||
sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
|
||||
# fix doc install path
|
||||
sed -i -e "s/docsdir/# docsdir/" \
|
||||
-e "s/docs_DATA =/# docs_DATA/" \
|
||||
-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
append-ldflags -L/usr/$(get_libdir)/hamlib
|
||||
econf $(use_with alsa) \
|
||||
$(use_with gpm) $(use_with hamlib) \
|
||||
$(use_with fftw fftw3)
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake DESTDIR="${D}" install
|
||||
dodoc AUTHORS ChangeLog doc/NAVOD.pdf
|
||||
if use suid ; then
|
||||
fperms 4711 /usr/bin/soundwrapper
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
elog "In order to use sound with tucnak add yourself to the 'audio' group"
|
||||
elog "and to key your rig via the parport add yourself to the 'lp' group"
|
||||
elog ""
|
||||
elog "tucnak can be used with the following additional packages:"
|
||||
elog " media-radio/cwdaemon : Morse output via code cwdaemon"
|
||||
elog " (No need to recompile)"
|
||||
if use suid ; then
|
||||
ewarn "You have choosen to install the little helper program 'soundwrapper'"
|
||||
ewarn "setuid by setting USE=suid. That helper is only needed if you"
|
||||
ewarn "want to use morse sidetone output via the PC speaker."
|
||||
ewarn ""
|
||||
ewarn "While the helper should be safe by design be aware that setting"
|
||||
ewarn "any program setuid is a security risk."
|
||||
fi
|
||||
}
|
Loading…
Reference in New Issue