app-accessibility/at-spi2-core: Version bump to 2.46.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

app-accessibility/at-spi2-core/Manifest

@@ -1 +1,2 @@
 DIST at-spi2-core-2.44.1.tar.xz 209780 BLAKE2B e76f0b0c478564181db774633dfc9613bdfa6c74c5c52878d877723e37605b7b7169fee45a9025b331e84bf5af8132eed50b388db9ac1aee0fec7776a633628a SHA512 8d85df75f886c4a19d829d14e5a9412b607b9cbe2d1b7ecb95b4082602f0624e90747fe955f96d378c3a52bc0e732074b97008bb34e6acc2722c7056b2c0504e
+DIST at-spi2-core-2.46.0.tar.xz 540600 BLAKE2B e3ed9915c39a9f71b64a9753c7f91208d15289fe09a9505b4766df7fa04c3e6e5cdc7b3702315eabbdf70f9fc08b4cca4546353485328ab101e2950a672885d6 SHA512 633af2c02fab3b8cb02e37f929ce80dd5ce28ca5641046ef5e25cb29299530b90028e6c6f318a0c098a4270bed3eab48fb55d6967a76bfadd2520f49de47c770

app-accessibility/at-spi2-core/at-spi2-core-2.46.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson-multilib systemd virtualx xdg
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="https://wiki.gnome.org/Accessibility https://gitlab.gnome.org/GNOME/at-spi2-core"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+IUSE="X gtk-doc +introspection"
+REQUIRED_USE="gtk-doc? ( X )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+RDEPEND="
+	>=sys-apps/dbus-1.5[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.67.4:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.54.0:= )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXtst[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+	)
+
+	!<dev-libs/atk-2.46.0
+	!<app-accessibility/at-spi2-atk-2.46.0
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.25
+		app-text/docbook-xml-dtd:4.3
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dsystemd_user_dir="$(systemd_get_userunitdir)"
+		$(meson_native_use_bool gtk-doc docs)
+		-Dintrospection=$(multilib_native_usex introspection)
+		-Dx11=$(usex X)
+		-Ddisable_p2p=false
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}

profiles/package.mask

@@ -33,6 +33,10 @@
 
 #--- END OF EXAMPLES ---
 
+# Matt Turner <mattst88@gentoo.org> (2022-10-02)
+# Masked for testing
+>=app-accessibility/at-spi2-core-2.46.0
+
 # Matt Turner <mattst88@gentoo.org> (2022-10-01)
 # Depends on lots of unmaintained packages:
 # 	- app-text/gnome-doc-utils