51 lines
1.1 KiB
Bash
51 lines
1.1 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=hatchling
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
|
|
inherit distutils-r1 pypi optfeature
|
|
|
|
DESCRIPTION="Utility for displaying installed packages in a dependency tree"
|
|
HOMEPAGE="
|
|
https://github.com/tox-dev/pipdeptree/
|
|
https://pypi.org/project/pipdeptree/
|
|
"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm arm64 x86"
|
|
|
|
RDEPEND="
|
|
>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
|
|
>=dev-python/pip-23.1.2[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
dev-python/hatch-vcs[${PYTHON_USEDEP}]
|
|
test? (
|
|
dev-python/graphviz[${PYTHON_USEDEP}]
|
|
dev-python/pytest-mock[${PYTHON_USEDEP}]
|
|
dev-python/virtualenv[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
PATCHES=(
|
|
# https://github.com/tox-dev/pipdeptree/pull/302
|
|
"${FILESDIR}/pipdeptree-2.17.0-expect-hpy-in-pypy-7.3.3.patch"
|
|
)
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
|
epytest -p pytest_mock
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature \
|
|
"visualising the dependency graph with --graph-output" \
|
|
dev-python/graphviz
|
|
}
|