dev-python/httpx: add 0.24.1 (from main)

dev-python/httpx/Manifest

@@ -0,0 +1,3 @@
+DIST httpx-0.24.1.gh.tar.gz 2168238 BLAKE2B 97a23e14635e8863b8f6fe80691ac4ae1706e0ce426d7cf9efa26ab54bb026d4a230a072bc16ec2f7edc08c768107ee00443626be1734d566bca8a190daa5ed0 SHA512 056741ef4e356f13adfcb66766489b39e79dbf4264d9780b8788c0934f7f3ff1a9b6bcb396a9f146e88315831f5399cebdd537c5a39c86b9b6bac3600d5560b6
+EBUILD httpx-0.24.1.ebuild 2005 BLAKE2B 5b511ba6d14ef63490acac57ab2d0ea38b9f448198e3c545aa5a079ec8f776c17c4bfa631c2a49fd07b62c39901ae1780118ecb628d00921ef673e05ac00df94 SHA512 802d507ebf9f2490d1d39275a259f2f42f0fe3dabc12d63b39534b5e3d9adab16387813184cfbd953ffd38709ef158a90798a88e4bd3c3b577ed3913ec80264c
+MISC metadata.xml 503 BLAKE2B 0f33f05816e101efa648da1736f1843eb0c50831ebcd83bd99d07a0cc33815a453fb660ff158659ff21e0f846d0ca7ec96246f5ae0d369d99a1ceece0fae8613 SHA512 44eb9d59716a2f9359f711590ce46f8e53706a6c373666e01ac4209c924cba4615925f161fd0aa8978b3370d7c246330b634a999a0116b127fc070d73b975133

dev-python/httpx/httpx-0.24.1.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+	https://www.python-httpx.org/
+	https://github.com/encode/httpx/
+	https://pypi.org/project/httpx/
+"
+SRC_URI="
+	https://github.com/encode/httpx/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 x86"
+IUSE="cli"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	<dev-python/httpcore-0.18[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-0.15[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	cli? (
+		=dev-python/click-8*[${PYTHON_USEDEP}]
+		=dev-python/pygments-2*[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/h2[${PYTHON_USEDEP}]
+		dev-python/socksio[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	if ! use cli; then
+		sed -i -e '/^httpx =/d' pyproject.toml || die
+	fi
+	sed -i -e '/rich/s:,<14::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/client/test_proxies.py::test_async_proxy_close
+		tests/client/test_proxies.py::test_sync_proxy_close
+	)
+
+	use cli || EPYTEST_IGNORE+=(
+		tests/test_main.py
+	)
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "HTTP/2 support" dev-python/h2
+	optfeature "SOCKS proxy support" dev-python/socksio
+	optfeature "Decoding for brotli compressed responses" dev-python/brotlicffi
+}

dev-python/httpx/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>b@edevau.net</email>
+    <name>Andreas Billmeier</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">httpx</remote-id>
+    <remote-id type="github">encode/httpx</remote-id>
+    <maintainer status="unknown">
+      <email>tom@tomchristie.com</email>
+      <name>Tom Christie</name>
+    </maintainer>
+  </upstream>
+</pkgmetadata>