Split the Repos

dev-python/pyjwt/Manifest

@@ -0,0 +1,2 @@
+DIST PyJWT-1.6.4.tar.gz 41694 BLAKE2B 59677d2f76a6f49be794d7cb796a5388b34fb8016dde9a069fa0494dfa91862b5cd9437e9231377fc7da10438a0a73ffbfe3afd2023cc21c5e166c93eb04fdaa SHA512 28c448d473f0409d11c2a97bef9f878800a78691250f55a46d79009b09faab0ac179133c4d4795ed9910dd7176adc9d6912189a5b4938f27ae441308e98d5e11
+EBUILD pyjwt-1.6.4.ebuild 1274 BLAKE2B aca14ed6abc283ac649ec62cf7eaff6cd1324cc2bf191d67ee67e8eea6a7ebcaa793756f1d1758d68a2f2ec2273640bca630cd27707abfd2bfa88c2e54a8a53f SHA512 76a505fe837f0d199960b90f699483b24c9a5da67c5632875f0a28090615e332a34a06c125cd0dfcb048c5355ed1ef45eff063433f76de0b1a4a2d81e965fbcd

dev-python/pyjwt/pyjwt-1.6.4.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} pypy )
+
+inherit distutils-r1 eutils
+
+MY_PN="PyJWT"
+
+DESCRIPTION="JSON Web Token implementation in Python"
+HOMEPAGE="https://github.com/progrium/pyjwt https://pypi.org/project/PyJWT/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE=" MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86"
+IUSE="test"
+
+RDEPEND=""
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/cryptography-1.4.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}"/${MY_PN}-${PV}
+
+python_prepare_all() {
+	find . -name '__pycache__' -prune -exec rm -rf {} \; || die "Cleaning __pycache__ failed"
+	find . -name '*.pyc' -exec rm -f {} \; || die "Cleaing *.pyc failed"
+
+	# enables coverage, we don't need that
+	rm setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	elog "Available optional features:"
+	optfeature "cryptography" dev-python/cryptography
+	optfeature "flake8" dev-python/flake8
+
+	ewarn "flake8 feature requires 'flake8-import-order' and 'pep8-naming', which are not in portage yet"
+}