2019-02-05 small changes

2019-02-05 11:35:15 +01:00
parent 09435e806b
commit 3fca96f6d6
11 changed files with 122 additions and 354 deletions
@@ -0,0 +1,3 @@
+DIST flake8-3.7.5.tar.gz 148039 BLAKE2B 4d1e793d92af549441542345709c1795bc1f16e883fc5cd3a6abcf7b0c42447652235ec3b8cc295a6c97d9813a814e04dfe18cb68c0bdb9f20005caa8f3d4212 SHA512 b7354012e5d66c8407bba062d0331fc1021bde4172f5d8014f37524218dfd489ce8d59a92edd86437a047251829ef0526663d823e14a09613f1d4dcf27f9365a
+EBUILD flake8-3.7.5.ebuild 1646 BLAKE2B b61ce7b2376c3abe6177c4f8dbf4b3658141720d05415e55f9f87fae374e2c434c610253a4d17b0d5ffa6b35708d245dc78d786d6baa9cf25f29b500caa87bcc SHA512 8e4203361704b7878d615cd8182eb743a9527aa7f6fa7566ada7207ffb08b6124b44c8162451a1105b0f68586347291427a19a1e5a403da1db8fa13b1e359b1e
+MISC metadata.xml 373 BLAKE2B af4d7678c87281f631048d3c49b0a642ceee1d771be2b662458888659b7c8e262c98adcd7bcb7f6ab251783998950725729ed35c887c004f8d8da87da81eda7d SHA512 449aa40152590e7103a4bf10006a33e6a0d5010a7846b0c5fbee8a78d99a3539995eccf441845c205bf48fc1e9b35cd7b1d6af0d98b469bdd06989baf8b88646
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="A wrapper around PyFlakes, pep8 & mccabe"
+HOMEPAGE="https://gitlab.com/pycqa/flake8 https://pypi.org/project/flake8/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+# requires.txt inc. mccabe however that creates a circular dep
+RDEPEND="
+	>=dev-python/pyflakes-2.0.0[${PYTHON_USEDEP}]
+	<dev-python/pyflakes-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/pycodestyle-2.5.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' 'python2*' 'pypy*' )
+	$(python_gen_cond_dep 'dev-python/configparser[${PYTHON_USEDEP}]' 'python2*' pypy )
+"
+PDEPEND="
+	>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${PDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Flake8 falsely assumes it needs pytest-runner unconditionally and will
+	# try to install it, causing sandbox violations.
+	sed -i -e "/setup_requires=\['pytest-runner'\],/d" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -v || die "Tests fail with ${EPYTHON}"
+}
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">flake8</remote-id>
+    <remote-id type="gitlab">pycqa/flake8</remote-id>
+  </upstream>
+</pkgmetadata>