dev-python/httpx: new package, add 0.23.2

Signed-off-by: Andreas Billmeier <b@edevau.net>

dev-python/httpx/Manifest

@@ -0,0 +1,3 @@
+DIST httpx-0.23.2.gh.tar.gz 2163739 BLAKE2B fe89a162749e8710f6392ce3a2eb887a4ee0053270ad4ce20cb74d6fb4e70a14c800755ea2b32166f11e3dcb74a3c7d50a3e3a0644fa489a89f9f65050b826a4 SHA512 49b0b8cd3ba3f4c18fcfaab5e9ac52bfacb80241aa2b8452542a274a4b203ef6b35d936ad7f9a0b1e0d9857b1394a4e388572676cd288c8fb20f78a6df3ada4c
+EBUILD httpx-0.23.2.ebuild 2183 BLAKE2B e73fafb05859fd765aeb92285be448e2e4e5c29eddb0a226984e189ad955fe3fae508fc1d8e2d1a062fd3fb12f061c1753acd11c84ddb9694da162f8001ade3a SHA512 3e86084b9fc8428e229cc3ad5c4fa35521dd1b5b23e8fd557e8e8406be2628353d53e505a9e538cce5dfc534d77c6ea51433d1867a5ea73953d47fb257abeb12
+MISC metadata.xml 503 BLAKE2B 0f33f05816e101efa648da1736f1843eb0c50831ebcd83bd99d07a0cc33815a453fb660ff158659ff21e0f846d0ca7ec96246f5ae0d369d99a1ceece0fae8613 SHA512 44eb9d59716a2f9359f711590ce46f8e53706a6c373666e01ac4209c924cba4615925f161fd0aa8978b3370d7c246330b634a999a0116b127fc070d73b975133

dev-python/httpx/httpx-0.23.2.ebuild

@@ -0,0 +1,87 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1 optfeature # docs
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+	https://www.python-httpx.org/
+	https://github.com/encode/httpx/
+	https://pypi.org/project/httpx/
+"
+SRC_URI="
+	https://github.com/encode/httpx/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	<dev-python/httpcore-0.17[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-0.15[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.3[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	cli? (
+		=dev-python/click-8*[${PYTHON_USEDEP}]
+		=dev-python/pygments-2*[${PYTHON_USEDEP}]
+		<dev-python/rich-13[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/h2[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-trio[${PYTHON_USEDEP}]
+		dev-python/socksio[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	if ! use cli; then
+		sed -i -e '/^httpx =/d' pyproject.toml || die
+	fi
+	sed -i -e '/rfc3986/s:,<2::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/client/test_proxies.py::test_async_proxy_close
+		tests/client/test_proxies.py::test_sync_proxy_close
+	)
+	local EPYTEST_IGNORE=(
+		# TODO: package multipart
+		tests/test_multipart.py
+	)
+
+	use cli || EPYTEST_IGNORE+=(
+		tests/test_main.py
+	)
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "HTTP/2 support" dev-python/h2
+	optfeature "SOCKS proxy support" dev-python/socksio
+	optfeature "Decoding for brotli compressed responses" dev-python/brotlicffi
+}

dev-python/httpx/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>b@edevau.net</email>
+    <name>Andreas Billmeier</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">httpx</remote-id>
+    <remote-id type="github">encode/httpx</remote-id>
+    <maintainer status="unknown">
+      <email>tom@tomchristie.com</email>
+      <name>Tom Christie</name>
+    </maintainer>
+  </upstream>
+</pkgmetadata>