# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{10..12} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1

DESCRIPTION="An implementation of the Debug Adapter Protocol for Python"
HOMEPAGE="https://github.com/microsoft/debugpy/ https://pypi.org/project/debugpy/"
SRC_URI="
	https://github.com/microsoft/${PN}/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 arm arm64 x86"

# This is completely broken
RESTRICT="test"

RDEPEND="dev-python/pydevd[${PYTHON_USEDEP}]"
BDEPEND="test? ( dev-python/pytest-timeout[${PYTHON_USEDEP}] )"

distutils_enable_tests pytest

python_prepare_all() {
	# Drop unnecessary and unrecognized option
	# __main__.py: error: unrecognized arguments: -n8
	# Do not timeout
	sed -e '/addopts/d' -e '/timeout/d' -i pytest.ini || die

	# Unbundle dev-python/pydevd
	#rm -r src/debugpy/_vendored tests/tests/test_vendoring.py || die

	distutils-r1_python_prepare_all
}
