gnome-extra/cinnamon: drop old
Package-Manager: Portage-3.0.20, Repoman-3.0.2 Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com> Closes: https://github.com/gentoo/gentoo/pull/21788 Signed-off-by: Joonas Niilola <juippis@gentoo.org>
This commit is contained in:
parent
1605a77a18
commit
eec27ea30e
|
@ -1,3 +1,2 @@
|
|||
DIST cinnamon-4.8.6.tar.gz 2378117 BLAKE2B ae98bf81aa3b2f26d33aa1b5a8109b50d969cb3568322159808c23d13fea6a11790d877a446b3ee4a54f5811fddfb5fca220f46bc213ffc2aa4560e344563f9d SHA512 827d93fa72213e00977d6318da25d9b03279666485ed4c4fd45ece9914c7481f39fa98c64940529a7459cc239783caa9427a2a702f77ffb77fb2c38073e42bbd
|
||||
DIST cinnamon-5.0.4.tar.gz 2397469 BLAKE2B d71d5c0a1d6386f77951629491fbc14f1c6e139b2a1f7ed87684ed3588897deecfe0158478ca52af18b18da250e8415822f56ce3ca758053a4b373b691627c6b SHA512 ac3eb6384fcbacab77a8a7bff1f28572df4ee62d3e9f0e0d02f9406ef690b3093355652201194d4c324bc13b6f806d27715434701a57c3b7544ad715aee27ad1
|
||||
DIST cinnamon-5.0.5.tar.gz 2397561 BLAKE2B c7f523bde1b36564155e90735a719de7d6d125dfd41c0559c68aaf02c2a3f963e7b039cabf3b47e88a527aaf333b1ad154cad04497752b3b75370dbd4491a9c4 SHA512 a54437a3b76748612e4ce3c357e94be6911087616d08cab1c20e37e9a97813eea29db2513bbc384489b223375fd02dbdb61a130f87a40fd8f353b7ca46df26eb
|
||||
|
|
|
@ -1,175 +0,0 @@
|
|||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{7,8,9} )
|
||||
PYTHON_REQ_USE="xml"
|
||||
|
||||
inherit meson gnome2-utils pax-utils python-single-r1 xdg
|
||||
|
||||
DESCRIPTION="A fork of GNOME Shell with layout similar to GNOME 2"
|
||||
HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon"
|
||||
SRC_URI="https://github.com/linuxmint/cinnamon/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2+"
|
||||
SLOT="0"
|
||||
IUSE="+gstreamer gtk-doc +nls +networkmanager"
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
|
||||
DEPEND="
|
||||
${PYTHON_DEPS}
|
||||
app-accessibility/at-spi2-atk:2
|
||||
>=dev-libs/glib-2.52.0:2[dbus]
|
||||
>=dev-libs/gobject-introspection-1.29.15:=
|
||||
dev-libs/libxml2:2
|
||||
>=gnome-extra/cinnamon-desktop-5.0:0=
|
||||
>=gnome-extra/cinnamon-menus-5.0
|
||||
>=gnome-extra/cjs-5.0[cairo]
|
||||
net-libs/libsoup:2.4[introspection]
|
||||
sys-apps/dbus
|
||||
>=sys-auth/polkit-0.100[introspection]
|
||||
virtual/opengl
|
||||
x11-libs/gdk-pixbuf:2[introspection]
|
||||
>=x11-libs/gtk+-3.12.0:3[introspection]
|
||||
>=x11-libs/libnotify-0.7.3:0=[introspection]
|
||||
x11-libs/libX11
|
||||
>=x11-libs/libXfixes-5.0
|
||||
x11-libs/pango[introspection]
|
||||
>=x11-libs/startup-notification-0.11
|
||||
>=x11-wm/muffin-5.0[introspection]
|
||||
|
||||
gstreamer? (
|
||||
media-libs/gst-plugins-base:1.0
|
||||
media-libs/gstreamer:1.0
|
||||
)
|
||||
networkmanager? (
|
||||
net-misc/networkmanager[introspection]
|
||||
)
|
||||
"
|
||||
# caribou used by onscreen keyboard
|
||||
# libtimezonemap used by datetime settings
|
||||
# iso-flag-png (unpackaged) used by keyboard layout settings
|
||||
RDEPEND="
|
||||
${DEPEND}
|
||||
>=app-accessibility/caribou-0.3
|
||||
dev-libs/keybinder:3[introspection]
|
||||
dev-libs/libtimezonemap
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/dbus-python[${PYTHON_USEDEP}]
|
||||
dev-python/distro[${PYTHON_USEDEP}]
|
||||
dev-python/pexpect[${PYTHON_USEDEP}]
|
||||
dev-python/pillow[${PYTHON_USEDEP}]
|
||||
dev-python/pycairo[${PYTHON_USEDEP}]
|
||||
dev-python/pygobject:3[${PYTHON_USEDEP}]
|
||||
dev-python/pyinotify[${PYTHON_USEDEP}]
|
||||
dev-python/pypam[${PYTHON_USEDEP}]
|
||||
dev-python/pytz[${PYTHON_USEDEP}]
|
||||
dev-python/setproctitle[${PYTHON_USEDEP}]
|
||||
dev-python/tinycss2[${PYTHON_USEDEP}]
|
||||
>=dev-python/xapp-2.2.0[${PYTHON_USEDEP}]
|
||||
')
|
||||
>=gnome-base/dconf-0.4.1
|
||||
>=gnome-base/gsettings-desktop-schemas-2.91.91
|
||||
>=gnome-base/libgnomekbd-2.91.4
|
||||
>=gnome-extra/cinnamon-control-center-5.0[networkmanager=]
|
||||
>=gnome-extra/cinnamon-screensaver-5.0
|
||||
>=gnome-extra/cinnamon-session-5.0
|
||||
>=gnome-extra/cinnamon-settings-daemon-5.0
|
||||
>=gnome-extra/nemo-5.0
|
||||
gnome-extra/polkit-gnome
|
||||
net-misc/wget
|
||||
sys-apps/accountsservice[introspection]
|
||||
sys-power/upower[introspection]
|
||||
>=x11-libs/xapps-2.2.0[introspection]
|
||||
x11-misc/xdg-utils
|
||||
x11-themes/adwaita-icon-theme
|
||||
x11-themes/gnome-themes-standard
|
||||
|
||||
nls? (
|
||||
>=gnome-extra/cinnamon-translations-5.0
|
||||
)
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-util/intltool-0.40
|
||||
>=sys-devel/gettext-0.17
|
||||
virtual/pkgconfig
|
||||
|
||||
gtk-doc? ( dev-util/gtk-doc )
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
# Fix backgrounds path as cinnamon doesn't provide them
|
||||
# https://github.com/linuxmint/Cinnamon/issues/3575
|
||||
"${FILESDIR}"/${PN}-3.8.0-gnome-background-compatibility.patch
|
||||
|
||||
# Use wheel group instead of sudo (from Fedora/Arch)
|
||||
# https://github.com/linuxmint/Cinnamon/issues/3576
|
||||
"${FILESDIR}"/${PN}-3.6.6-wheel-sudo.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
xdg_src_prepare
|
||||
|
||||
# Add polkit agent to required components
|
||||
# https://github.com/linuxmint/Cinnamon/issues/3579
|
||||
sed -i "s/'REQUIRED', '/&polkit-cinnamon-authentication-agent-1;/" meson.build || die
|
||||
|
||||
# shebang fixing craziness
|
||||
local p
|
||||
for p in $(grep -rl '#!.*python3' || die); do
|
||||
python_fix_shebang "${p}"
|
||||
done
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
$(meson_use gstreamer build_recorder)
|
||||
$(meson_use gtk-doc docs)
|
||||
-Ddisable_networkmanager=$(usex networkmanager false true)
|
||||
-Dpy3modules_dir="$(python_get_sitedir)"
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
|
||||
python_optimize "${D}$(python_get_sitedir)"
|
||||
python_optimize "${ED}"/usr/share/cinnamon/
|
||||
|
||||
# Required for gnome-shell on hardened/PaX, bug #398941
|
||||
pax-mark mr "${ED}"/usr/bin/cinnamon
|
||||
|
||||
# Doesn't exist on Gentoo, causing this to be a dead symlink
|
||||
rm "${ED}/etc/xdg/menus/cinnamon-applications-merged" || die
|
||||
|
||||
# Ensure authentication-agent is started, bug #523958
|
||||
# https://github.com/linuxmint/Cinnamon/issues/3579
|
||||
insinto /etc/xdg/autostart/
|
||||
doins "${FILESDIR}"/polkit-cinnamon-authentication-agent-1.desktop
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
gnome2_schemas_update
|
||||
|
||||
if use gstreamer; then
|
||||
if ! has_version 'media-libs/gst-plugins-good:1.0' || \
|
||||
! has_version 'media-plugins/gst-plugins-vpx:1.0'; then
|
||||
ewarn "To make use of Cinnamon's built-in screen recording utility,"
|
||||
ewarn "you need to either install media-libs/gst-plugins-good:1.0"
|
||||
ewarn "and media-plugins/gst-plugins-vpx:1.0, or use dconf-editor to change"
|
||||
ewarn "org.cinnamon.recorder/pipeline to what you want to use."
|
||||
fi
|
||||
else
|
||||
ewarn "Cinnamon's built-in screen recording utility is not installed"
|
||||
ewarn "because gstreamer support is disabled."
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_pkg_postinst
|
||||
gnome2_schemas_update
|
||||
}
|
Loading…
Reference in New Issue