x11-terms/guake: add 3.8.0

Enabled tests, added py3.10, and fixed prefix support.

Switched to github tarball given pypi is both outdated and
lacking tests.

paths.py / schemas are bit of a handful to get right, there's
likely a better way to work this out but going with this for now.

Closes: https://bugs.gentoo.org/811537
Closes: https://bugs.gentoo.org/818793
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

x11-terms/guake/Manifest

@@ -1 +1,2 @@
 DIST guake-3.7.0.tar.gz 1215186 BLAKE2B ff60f83fce5fbdd3712e261bbb72247cdcb311b8208af75007183bced88fcc2d2ebe3c49b76e2264786246444e9d07a41f884de949112c249277717070d64c11 SHA512 578c42ed41049acd253e0c409a9ecb103c7f71679fc5efdd94c60461b952ac77c836e59439361e1cd70e5fe6785ab4c15e7bf73b9f4c7d23b47c77468fa05f62
+DIST guake-3.8.0.tar.gz 1125090 BLAKE2B 72ee6b5e93c3433fcc2863d2b0aa198326cc4889126454040ce870fdeaa0ba110723410355ae49b5e2e4876fcad3f9d849873adaddfcf1ecfa83dc1583db57eb SHA512 6e0bb6b4a0c92c163bd6151c65936a38d93624166af5a4e2b042f9ade7f28683c8e8fad802b23a07edd478e2dd3b99a559069c9935f1154585be936d1b7a96ed

x11-terms/guake/guake-3.8.0.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 gnome2-utils virtualx xdg-utils
+
+DESCRIPTION="Drop-down terminal for GNOME"
+HOMEPAGE="http://guake-project.org/"
+SRC_URI="https://github.com/Guake/guake/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="utempter"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	dev-libs/keybinder:3[introspection]
+	x11-libs/libnotify[introspection]
+	x11-libs/libwnck:3[introspection]
+	x11-libs/vte:2.91[introspection]
+	utempter? ( sys-libs/libutempter )"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pbr[${PYTHON_USEDEP}]
+		test? (
+			dev-python/pyfakefs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+		)
+	')
+	dev-libs/glib:2
+	gnome-base/gsettings-desktop-schemas
+	sys-devel/gettext"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	emake PREFIX="${EPREFIX}/usr" prepare-install # paths.py.in -> paths.py
+
+	rm pyproject.toml || die # pytest fails if toml isn't installed
+
+	export PBR_VERSION=${PV} # needed if using github's tarball
+}
+
+python_test() {
+	# uses /usr/bin/bash if SHELL is not exported
+	SHELL=${SHELL} virtx distutils-r1_python_test
+}
+
+python_install() {
+	# done here so tests don't use the system's
+	sed -e "/^SCHEMA_DIR/s|=.*|= \"${EPREFIX}/usr/share/glib-2.0/schemas\"|" \
+		-e "/def get_default_data_dir/{n;s|=.*|= \"${EPREFIX}/usr/share/guake\"|}" \
+		-i "${BUILD_DIR}"/lib/guake/paths.py || die
+	rm -r "${BUILD_DIR}"/lib/guake/tests || die
+
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install-{locale,schemas}
+
+	dodoc NEWS.rst README.rst
+
+	mv "${D}"/{,"${EPREFIX}"/usr/share/}metainfo || die
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}