xfce-base/xfce4-panel: Bump to 4.16.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2021-02-25 15:52:27 +01:00
parent 275e5b7dbd
commit 3edaa39227
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
2 changed files with 72 additions and 0 deletions

View File

@ -1 +1,2 @@
DIST xfce4-panel-4.16.1.tar.bz2 1381003 BLAKE2B 103d1b60c13758ad5e3f139d3bc66923e648540195c7a71fb6c39bcdb06b109f620ced42b7eb6c36ccf5a833e97957c373e760feab3f062c5a7ecd3038803366 SHA512 ec55a9812d61db755ea56a87ea1b709af2870703fc0e5a45797406f2f4c78e8afecd6e1bc081f3618a81030c9c0595ae8edbb29731d4bef3750e202bbf35e99c
DIST xfce4-panel-4.16.2.tar.bz2 1381569 BLAKE2B d4b8455e31f942d0facfc0d90b14fb050142b3d8b3d0e61d5b687f973769e2888ea7f058c4f6a86f96dbd67329719ef49e72896774ac36591c2793847aa411ba SHA512 25b817a9abc4cea57cd29c4558236a5581a03ccb50796c83f7ca1b292e8aa83c7a39b089619959b6f6fd9c5c8bbdf950d9bba1b5c4fb3d0a95cabad8a9ca763d

View File

@ -0,0 +1,71 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit vala xdg-utils
DESCRIPTION="Panel for the Xfce desktop environment"
HOMEPAGE="https://www.xfce.org/projects/"
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="+dbusmenu introspection vala"
REQUIRED_USE="vala? ( introspection )"
RDEPEND=">=dev-libs/glib-2.50
>=x11-libs/cairo-1
>=x11-libs/gtk+-3.22:3[introspection?]
x11-libs/libX11
x11-libs/libwnck:3
>=xfce-base/exo-0.11.2:=
>=xfce-base/garcon-0.5:=
>=xfce-base/libxfce4ui-4.15.8:=
>=xfce-base/libxfce4util-4.15.6:=[introspection?]
>=xfce-base/xfconf-4.13:=
dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
introspection? ( dev-libs/gobject-introspection:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
vala? ( $(vala_depend) )
dev-lang/perl
dev-util/gtk-doc-am
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
"
src_prepare() {
# stupid vala.eclass...
default
}
src_configure() {
local myconf=(
$(use_enable introspection)
$(use_enable dbusmenu dbusmenu-gtk3)
$(use_enable vala)
)
use vala && vala_src_prepare
econf "${myconf[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
xdg_icon_cache_update
xdg_desktop_database_update
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}