app-text/sigil: add 1.8.0, enable py3.10

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Arthur Zamarin 2021-10-25 20:12:24 +03:00
parent f93c7a9aef
commit 1eb798bf02
No known key found for this signature in database
GPG Key ID: 02A0AF503D120504
2 changed files with 73 additions and 0 deletions

View File

@ -1 +1,2 @@
DIST sigil-1.7.0.tar.gz 21315598 BLAKE2B 29f7c682925d1e1bbff082e96b747ce32df82d78406ccd984b4f8de1f01944c35aa86587ce47a18687d5fe281b8cb656085b52d3a1e72ed17862501121d9d134 SHA512 9918bb0bfbe3d068c95bb31cd84a37a0fac6dd6be9e94cb382e8c0140cdb375f47384f33c62fdff7f27aed379037a4a64e8d4a1065ae297bb389e2be78597c16
DIST sigil-1.8.0.tar.gz 21217901 BLAKE2B 78615652859d1f61bab18b1b248d342dc6892943a2310659859ab577981c4452fbaeb567758097427453c8dfe95e42b499616a423b5c11b42238f763ac0653c8 SHA512 1a911aac996d3519f501820f8da9c810db9793063e481a6169288d402ef7e6b797308cf7ca5517162d0eb4d80f38f968627bca676b724ea5be5109c427473c95

View File

@ -0,0 +1,72 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
PYTHON_REQ_USE="tk"
inherit xdg cmake python-single-r1
DESCRIPTION="Multi-platform WYSIWYG ebook editor for ePub format"
HOMEPAGE="https://sigil-ebook.com/ https://github.com/Sigil-Ebook/Sigil"
SRC_URI="https://github.com/Sigil-Ebook/Sigil/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${P^}"
LICENSE="GPL-3+ Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+plugins system-mathjax"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
${PYTHON_DEPS}
app-text/hunspell:=
dev-libs/libpcre:3=[pcre16]
$(python_gen_cond_dep '
dev-python/css-parser[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]')
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtprintsupport:5
dev-qt/qtwebengine:5[widgets]
dev-qt/qtwidgets:5
sys-libs/zlib[minizip]
plugins? ( $(python_gen_cond_dep '
dev-python/chardet[${PYTHON_USEDEP}]
dev-python/cssselect[${PYTHON_USEDEP}]
dev-python/dulwich[${PYTHON_USEDEP}]
dev-python/html5lib[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
dev-python/regex[${PYTHON_USEDEP}]') )
system-mathjax? ( dev-libs/mathjax )
"
DEPEND="${RDEPEND}"
BDEPEND="
${PYTHON_DEPS}
dev-qt/linguist-tools:5
"
DOCS=( ChangeLog.txt README.md )
src_configure() {
local mycmakeargs=(
-DINSTALL_BUNDLED_DICTS=0
-DUSE_SYSTEM_LIBS=1
-DSYSTEM_LIBS_REQUIRED=1
-DPYTHON_EXECUTABLE="${PYTHON}"
-DPYTHON_LIBRARY="$(python_get_library_path)"
-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
)
use system-mathjax && mycmakeargs+=( -DMATHJAX_DIR="${EPREFIX}"/usr/share/mathjax )
cmake_src_configure
}
src_install() {
cmake_src_install
python_fix_shebang "${ED}"/usr/share/sigil/
python_optimize "${ED}"/usr/share/sigil/
}